home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 47.7z / BS1 part 47 / ImageMaster RT v1.50b (1994)(Black Belt Systems)(Disk 6 of 7)[HD].7z / ImageMaster RT v1.50b (1994)(Black Belt Systems)(Disk 6 of 7)[HD].adf / piarc.lzh.parta / FlickWR1.rexx < prev    next >
OS/2 REXX Batch file  |  1994-03-17  |  5KB  |  162 lines
  1. /*
  2.    This is the opening phase of the ARexx scripts for making Flicks's
  3.    
  4.    This script gets three things from the user and sticks them into a
  5.    file in ram: so the other three phases of the process will know what
  6.    to do.
  7.    
  8.      1 - The name of the Flick to create or extend is obtained
  9.      2 - The name template to be used for the individual frames is obtained.
  10.      3 - The number of jiffies between frames.
  11.  */
  12.  
  13. /*
  14.  * open rexxsupport.library -- needed for some functions
  15.  */
  16. if ~show('L',"rexxsupport.library") then do
  17.   if addlib('rexxsupport.library',0,-30,0) then do
  18.       /* everything's ok */
  19.     end;
  20.   else do
  21.     say 'We Have A Library Problem, Unable To Load "rexxsupport.library"';
  22.     say 'Cannot operate FlickWR.rexx without this library - sorry!';
  23.     exit 10;
  24.     end;
  25.   end;
  26.  
  27. /*
  28.  * This will automatically direct the script to the proper
  29.  * software, if it is running.
  30.  */
  31. prtnme = 'IP_Port'; /* assume Image Professional */
  32. if show('P','IP_Port') = 0 then do
  33.   if show('P','IM_Port') = 0 then do
  34.     say "Can't find image processor's ARexx port!!!"; /* not running? */
  35.     say "This script requires IP, IM or IM F/c to run!";
  36.     exit(20);
  37.     end;
  38.   else do
  39.     prtnme = 'IM_Port'; /* That's the thing about assumptions... */
  40.     end;                 /* We make em, user's break em.          */
  41.   end;
  42.  
  43. options;
  44. address;
  45.  
  46.   prevpath = 'ram:'; /* put user in ram to start with... */
  47.  
  48.   if show('C',flickpath) = 1 then do
  49.     prevpath = getclip(flickpath);
  50.     end;
  51.  
  52.   address(prtnme);
  53.  
  54.   options results;
  55.   'filerequest "'||prevpath||'","'||bufname||'",".flc","Make Flick"';
  56.   flickfile = result;
  57.   options;
  58.  
  59.   if flickfile = 'FR_CANCELLED' then do
  60.     address(prtnme);
  61.     'imtofront';
  62.     exit 0;
  63.     end;
  64.   else do
  65.     flickfile = expandfilename(flickfile);
  66.     thispath = gimmepath(flickfile);
  67.     call setclip(flickpath,thispath);
  68.   end;
  69.  
  70.   options results;
  71.   'askprop '||'"# of jiffies (60th / sec) between frames?" 2 1 180'
  72.   jiffies = result;
  73.   options;
  74.  
  75.   res = open(fhandle,flickfile,'read');
  76.   if res ~= 0 then do
  77.     call close(fhandle);
  78.     address(prtnme);
  79.     options results;
  80.     'askyn '||'"Create New Flick" "Append to Existing Flick"'
  81.     prefs = result;
  82.     if prefs = 0 then do
  83.       address command 'c:delete >nil: '||flickfile;
  84.       end;
  85.     if prefs = 1 then do
  86.       options results;
  87.       'askyn '||'"Truncate before appending" "Append as is"'
  88.       prefs = result;
  89.       if prefs = 0 then do
  90.         address command 'cmpi:FlickWR -t '||jiffies||' '||flickfile;
  91.         end;
  92.       end;
  93.     end;
  94.  
  95.   address(prtnme);
  96.   options results;
  97.   'askyn '||'"Create loop frame" "No loop frame"'
  98.   prefs = result;
  99.  
  100.   call open(fhandle,'ram:IP_FLICKWR.CFG','write');      /* open the file */
  101.   junk = writeln(fhandle, jiffies);
  102.   junk = writeln(fhandle, flickfile);
  103.   junk = writeln(fhandle, prefs);
  104.   call close(fhandle);                     /* close the file    */
  105.  
  106.   address(prtnme);
  107.   'finish';
  108.   exit 0;
  109.  
  110.  
  111. /*
  112.  * gimmepath
  113.  *
  114.  * This takes the provided argument and sucks the path out of it, then
  115.  * returns that path to the caller, sans file name.
  116.  */
  117. gimmepath:
  118.   arg fullnamegx;
  119.     tempgx = reverse(fullnamegx);
  120.     lengx = length(fullnamegx);   /* get length of string */
  121.     slashdex = index(tempgx,'/'); /* first occurance of '/' from right */
  122.     colondex = index(tempgx,':');  /* first occurance of ':' from right */
  123.     seploc = 0; /* assumes current dir, no path supplied */
  124.     if slashdex ~= 0 then do /* we assume we are in a DIR */
  125.       seploc = (lengx - slashdex)+1;
  126.       end;
  127.     else do
  128.       if colondex ~= 0 then do /* we assume we are on a device */
  129.         seploc = (lengx - colondex)+1;
  130.         end;
  131.       end;
  132.   gxname = substr(fullnamegx,seploc+1); /* if you ever need it */
  133.   gxpath = left(fullnamegx,seploc);
  134.   return(gxpath);
  135.  
  136. /*
  137.  * Since this script can't be expected to know where the CD of the user
  138.  * is when this cmd is invoked, we have to check the path the user
  139.  * provides - if it's not specified right from a root, then we have
  140.  * to make it a complete specification from the root.
  141.  */
  142. expandfilename:
  143.   parse arg jfile;
  144.   if index(jfile,':') = 0 then do
  145.     curdir = pragma(D);
  146.     if right(curdir,1) ~= ':' then do
  147.       if right(curdir,1) ~= '/' then do
  148.         if curdir ~= '' then do
  149.           curdir = curdir || '/';
  150.           end;
  151.         end;
  152.       end;
  153.     jfile = curdir||jfile;
  154.     end;
  155.   return(jfile);
  156.  
  157. rvalue:
  158.   wordnum = c2d(readch(fhandle,1)) * 256;
  159.   wordnum = wordnum + c2d(readch(fhandle,1));
  160.   return wordnum;
  161.  
  162.